Arduino Software and Hardware Based Button Debouncing

This, button debouncing, is vital for using any type of button with the Arduino. A bounce is referring to when the switch is pressed, and since its mechanical, its not a clean one time press. There are a whole bunch of tiny connections between the two sides of the switch before the button is actually pressed fully, and so the Arduino incorrectly counts those tiny connections as presses. So, to fix this we need to debounce the switch and make those tiny connections not count as button presses. There are two ways to do this; through software, and with hardware.

Software Debouncing:

Software based debouncing is by far the most common and easier to implement depending on where your skills are(HW vs SW). Basically, the Arduino runs in a loop(like it normally does) and when it detects the switch as "HIGH" it records the time. then it checks again, and if its still "HIGH" and its been high for long enough to be considered a full press of the switch, it sets a value or something saying that a button was completely pressed. Here is a ton of different ways to do software debouncing. This is some code from the Arduino website that works perfectly:

const int buttonPin = 2;     // the number of the pushbutton pin
const int ledPin =  13;      // the number of the LED pin

// Variables will change:
int ledState = HIGH;         // the current state of the output pin
int buttonState;             // the current reading from the input pin
int lastButtonState = LOW;   // the previous reading from the input pin

// the following variables are long's because the time, measured in miliseconds,
// will quickly become a bigger number than can be stored in an int.
long lastDebounceTime = 0;  // the last time the output pin was toggled
long debounceDelay = 50;    // the debounce time; increase if the output flickers

void setup() {
  pinMode(buttonPin, INPUT);
  pinMode(ledPin, OUTPUT);
}

void loop() {
  // read the state of the switch into a local variable:
  int reading = digitalRead(buttonPin);

  // check to see if you just pressed the button 
  // (i.e. the input went from LOW to HIGH),  and you've waited 
  // long enough since the last press to ignore any noise:  

  // If the switch changed, due to noise or pressing:
  if (reading != lastButtonState) {
    // reset the debouncing timer
    lastDebounceTime = millis();
  } 
  
  if ((millis() - lastDebounceTime) > debounceDelay) {
    // whatever the reading is at, it's been there for longer
    // than the debounce delay, so take it as the actual current state:
    buttonState = reading;
  }
  
  // set the LED using the state of the button:
  digitalWrite(ledPin, buttonState);

  // save the reading.  Next time through the loop,
  // it'll be the lastButtonState:
  lastButtonState = reading;
} 

Hardware Debouncing: 

This, on the other hand is used much less. The big point here is that it uses a 100nf cap. This cap is charged as soon as the circuit gets power and since the cap is fully charged there is no current flowing and the pin will read LOW. As soon as the button is pressed, the cap is discharged and the pin will read HIGH. Using this method, all that is needed for code is a simple digitalRead to check the status of the button.

#define buttonPin  2    // the number of the pushbutton pin
#define ledPin  13      // the number of the LED pin

void setup() {
  pinMode(buttonPin, INPUT);
  pinMode(ledPin, OUTPUT);
}

void loop() {
   digitalWrite(ledPin, digitalRead(buttonPin));  //sets the LED to current state of button
}